案例描述

如图所示有一长30m的简支钢梁，截面尺寸为0.4m×0.4m的正方形，简支梁跨中承受100kN的荷载，试分别采用梁单元和实体单元对该模型进行建模计算，输出跨中挠度和弯矩图、剪力图等计算结果。

矩形截面简支钢梁示意图

采用Solid185单元建模分析

单元介绍

Solid185为3D 8节点实体单元，每个节点有3个自由度，即UX、UY和UZ，是ANSYS中常用的一个实体单元，其几何模型如下图所示。

Solid185单元几何图示

分析命令流

finish
/clear
/CONFIG,NRES,999999      !!!配置参数命令     
/NERR,9999999,99999999   !!!关闭警告信息

/PREP7    !!!进入前处理器
!-------------------------定义单元类型
ET,1,solid185

!--------------------------材料属性
!钢材
MP,EX,1,2.1E11  !弹模
MP,PRXY,1,0.3   !泊松比
MP,DENS,1,7850  !密度

!--------------------------建立几何模型
BLC4,,,0.4,0.4,30

!在跨中切出1m宽度的加载面
WPCSYS,-1
WPOFFS,,,15-0.5
VSBW,ALL
WPOFFS,,,1
VSBW,ALL
WPCSYS,-1

!--------------------------网格划分
ALLSEL
VATT,1,,1,,,,
LESIZE,ALL,0.25	!网格尺寸0.25m
VMESH,ALL

!--------------------------施加载荷约束
!定义质量单元
ET,2,MASS21
KEYOPT,2,3,0	!6个自由度
M=0.0001	!给定一个很小的质量不影响计算结果
R,2,M,M,M	!质量在单元坐标系三个方向上的分量,不具有实际意义

!创建主节点和质量单元
N,10000,0.2,0.2,0
N,10001,0.2,0.2,30
TYPE,2
REAL,2
E,10000
E,10001

!设置刚性区域并关联自由度
NSEL,S,LOC,Z,0
CERIG,10000,ALL,ALL
NSEL,S,LOC,Z,30
CERIG,10001,ALL,ALL

!在主节点上施加简支约束
ALLSEL
D,10000,,,,,,UX,UY,UZ,ROTZ
D,10001,,,,,,UX,UY,ROTY

!选中跨中1m范围内的面施加面荷载
ASEL,S,LOC,Z,14.5,15.5
ASEL,R,LOC,Y,0.4
SFA,ALL,,PRES,100E3/1/0.4	!施加面荷载100kN/m2

!--------------------------求解
/SOLU
ANTYPE,0		!静力分析
ALLSEL
SOLVE

关键问题分析

实体模型如何施加简支约束？

从Solid185的单元属性中可以发现，该单元的节点只有三个方向的平动位移，无论怎么对节点施加约束都不能使其自由转动。网络上绝大部分关于实体模型施加简支约束的回答，都是让一边约束UX、UY和UZ，另一边只约束UY，但使用该方法并不能模拟出简支梁的变形和受力特性。

本案例中使用的是CERIG命令，将简支梁端面设置为刚性区域并与主节点进行自由度关联，从而通过对主节点施加简支约束条件，使被关联的实体梁模型也能达到简支约束的效果。矩形截面钢梁端面自由度约束情况如下图所示。

矩形钢梁端面设置刚性区域并进行自由度关联

整体模型约束情况

求解完成后，查看Y向位移云图可以发现，矩形梁变形沿跨中截面完全对称，两端面都能绕X轴自由旋转，跨中截面最大竖向位移为0.117m。

矩形钢梁Y向位移云图

端面区域变形放大图

在后处理中使用FSUM命令还可得到整个模型的合力计算结果如下，可以看出合力FY=-100kN，与外力值一致。

模型合力计算结果

实体模型如何提取截面内力绘制弯矩图和剪力图

在内力提取方面，梁单元可以通过定义单元表轻松输出弯矩、剪力图，但实体单元模型就没有那么简单。ANSYS中获取实体结构截面内力的方法主要有两种：单元节点力求和法（FSUM命令）和面操作法（SUEVAL命令）。本案例中使用单元节点力求和法来提取各截面内力，命令流如下：

!--------------------------实体单元截面内力提取
!!================单元节点力求和法=================!!
/post1
Snum=30/0.25+1			!提取截面总数，每隔0.25m提取一次
!定义数据存储数组
*DIM,FY_gap,ARRAY,Snum
*DIM,MX_gap,ARRAY,Snum

*DO,I,1,Snum
	ESEL,S,CENT,Z,0.25*(I-1),0.25*I
	NSLE
	NSEL,R,LOC,Z,,0.25*(I-1)
	spoint,,0.49,0.5,0.25*(I-1)	!求和点
	fsum	!合力
	*GET,FY_1,FSUM,0,ITEM,FY
	*GET,MX_1,FSUM,0,ITEM,MX
	FY_gap(I)=FY_1
	MX_gap(I)=MX_1
*ENDDO

!!!导出应力信息
/post1
*CREATE,MX_inf,mac,  !定义宏文件
*CFOPEN,MX,txt,,  	!TXT文件名
*VWRITE,MX_gap(1)	!将MX_CEN数组写入MX.TXT
(E16.4,E16.4,E16.4)     
!输出格式设置，F8.2，小数共8位，小数点后2位，E指数形式
*CFCLOS
*END
MX_inf
/delete,MX_inf,mac

*CREATE,FY_inf,mac, 
*CFOPEN,FY,txt,, 
*VWRITE,FY_gap(1)
(E16.4,E16.4,E16.4)     
!输出格式设置，F8.2，小数共8位，小数点后2位，E指数形式
*CFCLOS
*END
FY_inf
/delete,FY_inf,mac

命令流输出的弯矩和剪力文件

运行完内力提取命令后，会在ANSYS的工作目录生成两个TXT文件，里面存放的是提取到的各截面弯矩MX和剪力FY，将数值导入到EXCEL即可绘制出矩形截面梁实体模型的弯矩图和剪力图。从弯矩和剪力的分布图中也可以看出该梁处于简支受力状态，弯矩最大值出现在跨中区域，最大值为737.5kN×m。

弯矩图

剪力图

与梁单元计算结果对比

梁单元分析命令流

finish
/clear
/CONFIG,NRES,999999      !!!配置参数命令     
/NERR,9999999,99999999   !!!关闭警告信息

/PREP7    !!!进入前处理器
!-------------------------定义单元类型
ET,1,BEAM188

!定义截面
SECTYPE,1,BEAM,rect	!定义工字形截面
SECDATA,0.4,0.4	!截面参数
!SECPLOT,1,0 !显示截面

!--------------------------材料属性
!钢材
MP,EX,1,2.1E11  !弹模
MP,PRXY,1,0.3   !泊松比
MP,DENS,1,7850  !密度

!--------------------------建立几何模型
!定义关键点
K,1,0,0,0
K,2,0,0,30

LSTR,1,2	!梁线

!--------------------------网格划分
ALLSEL
LATT,1,,1,,,,1
LESIZE,ALL,0.25
LMESH,ALL

!--------------------------施加载荷约束
!简支约束
DK,1,,,,0,UX,UY,UZ,ROTZ,,, 
DK,2,,,,0,UX,UY,ROTY,,,, 

NSEL,S,LOC,Z,15	!跨中节点
F,ALL,FY,-100E3	!施加集中荷载100kN

!--------------------------求解
/SOLU
ANTYPE,0	!静力分析
ALLSEL
SOLVE

!--------------------------后处理
/POST1
PLNSOL,U,Y,0,1.0	!竖向位移云图
!剪力图
ETABLE,SFY1,SMISC,6
ETABLE,SFY2,SMISC,19
PLLS,SFY1,SFY2
!弯矩图
ETABLE,MZ1,SMISC,3
ETABLE,MZ2,SMISC,16
PLLS,MZ1,MZ2