常用ANSYS后处理命令流（附详细解释）,持续更新中...

ANSYS的结果后处理一直是很多人学起来很头疼的部分，因为这部分涉及到的内容很多，许多书本、教学视频都没能写得全面且系统。我在学习过程中也感觉到很困难，所以我从很多个ANSYS计算案例中积累了大量的命令流处理方法，包括但不限于后处理部分，在此陈列，以防遗忘。

一些基础知识

ANSYS有限元分析完成后，会在工作目录生成一个结果文件，对不同的分析结果文件的后缀名不同，例如：结构分析求解的结果文件名为Jobname.rst，磁场分析为Jobname.rmg，热分析为Jobname.rth，流体分析为Jobname.rfl。后处理器就是用来分析处理结果文件的工具。

根据有限元理论，ANSYS的计算结果分为基础解和派生解。基础解是每个节点的自由度解，如结构求解中的位移解；派生解是由基础解计算出来的，比如结构求解中单元的应力应变等。

后处理命令流

获取节点最大应力、应变

/POST1	!通用后处理
/GRAPHICS,FULL	!关闭PowerGraphics选项,默认为激活状态云图显示的是平均值偏大
ALLSEL
ESEL,S,MAT,,3		!选择材料编号为3的单元
NSLE						!选中单元对应的所有节点
NSORT,S,EQV,0,0,ALL		!降序排列节点等效应力代数值
*GET,MAX_SEQV,SORT,0,MAX					!最大应力值
*GET,NUM_MAXSEQV,SORT,0,IMAX			!最大应力值对应节点号

NSORT,EPTO,EQV,0,0,ALL
*GET,MAX_EPTOEQV,SORT,0,MAX				!最大应变值
*GET,NUM_MAXEPTOEQV,SORT,0,IMAX

*CREATE,WTXT_inf,mac, !定义宏文件
*CFOPEN,SMAX,txt,, 		!TXT文件名
	*VWRITE,NUM_MAXSEQV	!写入结果
	(E16.4,E16.4,E16.4)		!输出格式设置，F8.2，小数共8位，小数点后2位，E指数形式
	*VWRITE,MAX_SEQV
	(E16.4,E16.4,E16.4) 	!输出格式设置，F8.2，小数共8位，小数点后2位，E指数形式
*CFCLOS
WTXT_inf							!运行宏文件
/delete,WTXT_inf,mac	!删除宏文件

获取当前荷载步下的FY,等效于施加的外力,或计算结构质量

/post1
fsum                                !结构支座反力列表
*get,fanli,fsum,0,item,fy           !获取结构竖向支座反力总和
MASS=fanli*(-1)/9.8                 !结构质量
*status,MASS

绘制加载过程的荷载-位移曲线

/POST26
N1=7481	!节点编号
NSOL,2,N1,U,Y
PROD,3,2,,,,,,-1	!变量3将变量2反号
PROD,4,1,,,LOAD,,,F/1000 !变量3为时间乘以P0，并变为KN单位
!绘制变形过程的荷载位移曲线
/AXLAB,X,DISPLACEMENT(m)	!定义曲线横坐标标题
/AXLAB,Y,F(N)	!定义曲线纵坐标标题
XVAR,3				!指定变量2作为横坐标X变量
PLVAR,4				!绘制变量4关于变量3变化的曲线
FINISH

绘制钢筋的应力应变图

/POST1
ETABLE,STRES,LS,1	!定义单元表,轴向应力
PLLS,STRES,STRES	!绘制预应力筋的应力分布图

ETABLE,EPEAXL,LEPEL,1	!定义单元表,轴向弹性应变
PLLS,EPEAXL,EPEAXL		!绘制预应力筋的应变分布图

模态分析计算及振型频率结果导出

/solu
allsel
ANTYPE,2
MODOPT,subsp,10,,,,1    !!!子空间迭代法求解10阶模态
MXPAND,10,,,YES
LUMPM,OFF
ncnv,2
solve
finish

/post1
set,list					!列出10阶自振频率
!!============批量输出振型图================!!
/post1
NUM_MODAL=10      !!!输入需要模态分析的阶数
/SHOW,PNG			!输出PNG格式图片
PNGR,DEFAULT	!采用PNG缺省格式
/GFILE,2400		!像素为2400
/CMAP,DQMAP,CMP,,SAVE			!保存当前图形区设置
/RGB,INDEX,100,100,100,0	!将背景色设置为白色
/RGB,INDEX,0,0,0,15
*DO,I,1,NUM_MODAL			!每隔一个子步输出一幅图片
	SET,,, ,,, ,I	
	PLNSOL,U,SUM,0,1.0		!输出模态振型图片至ANSYS工作目录
*ENDDO
/SHOW,CLOSE					!PNG格式图片输出结束
/CMAP,DQMAP,CMP			!恢复图形区设置
/DELETE,DQMAP,CMP		!删除DAMAP.CMP文件h